Tạo một KQL queryset
Trong bước tiếp theo, bạn sẽ sử dụng khả năng phân tích dữ liệu nâng cao của Kusto Query Language để truy vấn hai bảng bạn đã tiếp nhận vào cơ sở dữ liệu.
1. Truy cập vào cơ sở dữ liệu KQL của bạn có tên là NycTaxiDB.
2. Chọn New related item > KQL Queryset
3. Nhập nyctaxiqs làm tên KQL queryset.
4. Chọn Create. KQL queryset mở ra với một số truy vấn mẫu tự động điền sẵn.
Truy vấn dữ liệu
Phần này sẽ hướng dẫn bạn qua một số khả năng truy vấn và hiển thị dữ liệu của KQL queryset. Sao chép và dán các truy vấn vào trình soạn thảo truy vấn của bạn để chạy và hiển thị kết quả.
1. Chạy truy vấn sau để trả về 10 địa điểm đón hàng hàng đầu ở New York City cho các xe Taxi Vàng.
Kusto
nyctaxitrips
| summarize Count=count() by PULocationID
| top 10 by Count
2. Truy vấn này thêm một bước vào truy vấn trước đó. Chạy truy vấn để tra cứu các khu vực tương ứng của 10 địa điểm đón hàng hàng đầu bằng cách sử dụng bảng Locations. Toán tử tra cứu mở rộng các cột của bảng sự kiện bằng giá trị được tra cứu trong một bảng chiều.
Kusto
nyctaxitrips
| lookup (Locations) on $left.PULocationID == $right.LocationID
| summarize Count=count() by Zone
| top 10 by Count
| render columnchart
3. KQL cũng cung cấp các chức năng máy học để phát hiện các ngoại lệ. Chạy truy vấn sau để kiểm tra các ngoại lệ trong số lời khuyên được khách hàng đưa ra ở quận Manhattan. Truy vấn này sử dụng hàm series_decompose_anomalies.
Kusto
nyctaxitrips
| lookup (Locations) on $left.PULocationID==$right.LocationID
| where Borough == "Manhattan"
| make-series s1 = avg(tip_amount) on tpep_pickup_datetime from datetime(2022-06-01) to datetime(2022-06-04) step 1h
| extend anomalies = series_decompose_anomalies(s1)
| render anomalychart with (anomalycolumns=anomalies)
Di chuột qua các điểm màu đỏ để xem giá trị của các ngoại lệ.
4. Bạn cũng có thể sử dụng sức mạnh dự đoán của hàm series_decompose_forecast. Chạy truy vấn sau để đảm bảo rằng có đủ xe taxi hoạt động ở quận Manhattan và dự đoán số lượng xe taxi cần mỗi giờ.
Kusto
nyctaxitrips
| lookup (Locations) on $left.PULocationID==$right.LocationID
| where Borough == "Manhattan"
| make-series s1 = count() on tpep_pickup_datetime from datetime(2022-06-01) to datetime(2022-06-08)+3d step 1h by PULocationID
| extend forecast = series_decompose_forecast(s1, 24*3)
| render timechart
Nguồn: https://learn.microsoft.com/en-us/fabric/real-time-analytics/tutorial-5-advanced-kql-query
